configure.ac 6.5 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220
  1. dnl Process this file with autoconf to produce a configure script.
  2. AC_INIT([file],[5.41],[christos@astron.com])
  3. AM_INIT_AUTOMAKE([subdir-objects foreign])
  4. m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  5. AC_CONFIG_HEADERS([config.h])
  6. AC_CONFIG_MACRO_DIR([m4])
  7. AC_MSG_CHECKING(for builtin ELF support)
  8. AC_ARG_ENABLE(elf,
  9. [ --disable-elf disable builtin ELF support],
  10. [if test "${enableval}" = yes; then
  11. AC_MSG_RESULT(yes)
  12. AC_DEFINE([BUILTIN_ELF], 1, [Define if built-in ELF support is used])
  13. else
  14. AC_MSG_RESULT(no)
  15. fi], [
  16. # enable by default
  17. AC_MSG_RESULT(yes)
  18. AC_DEFINE([BUILTIN_ELF], 1, [Define in built-in ELF support is used])
  19. ])
  20. AC_MSG_CHECKING(for ELF core file support)
  21. AC_ARG_ENABLE(elf-core,
  22. [ --disable-elf-core disable ELF core file support],
  23. [if test "${enableval}" = yes; then
  24. AC_MSG_RESULT(yes)
  25. AC_DEFINE([ELFCORE], 1, [Define for ELF core file support])
  26. else
  27. AC_MSG_RESULT(no)
  28. fi], [
  29. # enable by default
  30. AC_MSG_RESULT(yes)
  31. AC_DEFINE([ELFCORE], 1, [Define for ELF core file support])
  32. ])
  33. AC_MSG_CHECKING(for zlib support)
  34. AC_ARG_ENABLE([zlib],
  35. [AS_HELP_STRING([--disable-zlib], [disable zlib compression support @<:@default=auto@:>@])])
  36. AC_MSG_RESULT($enable_zlib)
  37. AC_MSG_CHECKING(for bzlib support)
  38. AC_ARG_ENABLE([bzlib],
  39. [AS_HELP_STRING([--disable-bzlib], [disable bz2lib compression support @<:@default=auto@:>@])])
  40. AC_MSG_RESULT($enable_bzlib)
  41. AC_MSG_CHECKING(for xzlib support)
  42. AC_ARG_ENABLE([xzlib],
  43. [AS_HELP_STRING([--disable-xzlib], [disable liblzma/xz compression support @<:@default=auto@:>@])])
  44. AC_MSG_RESULT($enable_xzlib)
  45. AC_MSG_CHECKING(for libseccomp support)
  46. AC_ARG_ENABLE([libseccomp],
  47. [AS_HELP_STRING([--disable-libseccomp], [disable libseccomp sandboxing @<:@default=auto@:>@])])
  48. AC_MSG_RESULT($enable_libseccomp)
  49. AC_MSG_CHECKING(for file formats in man section 5)
  50. AC_ARG_ENABLE(fsect-man5,
  51. [ --enable-fsect-man5 enable file formats in man section 5],
  52. [if test "${enableval}" = yes; then
  53. AC_MSG_RESULT(yes)
  54. fsect=5
  55. else
  56. AC_MSG_RESULT(no)
  57. fsect=4
  58. fi], [
  59. # disable by default
  60. AC_MSG_RESULT(no)
  61. fsect=4
  62. ])
  63. AC_CANONICAL_HOST
  64. case "$host_os" in
  65. mingw32*)
  66. MINGW=1
  67. ;;
  68. *)
  69. MINGW=0
  70. ;;
  71. esac
  72. AC_SUBST(MINGW)
  73. AM_CONDITIONAL(MINGW, test "$MINGW" = 1)
  74. AC_SUBST([pkgdatadir], ['$(datadir)/misc'])
  75. AC_SUBST(fsect)
  76. AM_CONDITIONAL(FSECT5, test x$fsect = x5)
  77. AC_SUBST(WARNINGS)
  78. dnl Checks for programs.
  79. AC_PROG_CC
  80. AC_USE_SYSTEM_EXTENSIONS
  81. AM_PROG_CC_C_O
  82. AC_C_BIGENDIAN
  83. AC_PROG_INSTALL
  84. AC_PROG_LN_S
  85. LT_INIT([disable-static pic-only])
  86. gl_VISIBILITY
  87. dnl Checks for headers
  88. AC_HEADER_MAJOR
  89. AC_HEADER_SYS_WAIT
  90. AC_CHECK_HEADERS(stdint.h fcntl.h inttypes.h unistd.h)
  91. AC_CHECK_HEADERS(utime.h wchar.h wctype.h)
  92. AC_CHECK_HEADERS(getopt.h err.h xlocale.h)
  93. AC_CHECK_HEADERS(sys/mman.h sys/stat.h sys/types.h sys/utime.h sys/time.h sys/sysmacros.h)
  94. if test "$enable_zlib" != "no"; then
  95. AC_CHECK_HEADERS(zlib.h)
  96. fi
  97. if test "$enable_bzlib" != "no"; then
  98. AC_CHECK_HEADERS(bzlib.h)
  99. fi
  100. if test "$enable_xzlib" != "no"; then
  101. AC_CHECK_HEADERS(lzma.h)
  102. fi
  103. AC_CHECK_TYPE([sig_t],[AC_DEFINE([HAVE_SIG_T],1,[Have sig_t type])],,[#include <signal.h>])
  104. dnl Checks for typedefs, structures, and compiler characteristics.
  105. AC_TYPE_OFF_T
  106. AC_TYPE_SIZE_T
  107. AC_CHECK_MEMBERS([struct stat.st_rdev])
  108. AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,[#include <time.h>])
  109. AC_STRUCT_TIMEZONE
  110. AC_STRUCT_TIMEZONE_DAYLIGHT
  111. AC_SYS_LARGEFILE
  112. AC_FUNC_FSEEKO
  113. AC_TYPE_MBSTATE_T
  114. AC_STRUCT_OPTION_GETOPT_H
  115. AC_TYPE_PID_T
  116. AC_TYPE_UINT8_T
  117. AC_TYPE_UINT16_T
  118. AC_TYPE_UINT32_T
  119. AC_TYPE_INT32_T
  120. AC_TYPE_UINT64_T
  121. AC_TYPE_INT64_T
  122. AC_TYPE_INTPTR_T
  123. AC_TYPE_UINTPTR_T
  124. AC_FUNC_MMAP
  125. AC_FUNC_FORK
  126. AC_FUNC_MBRTOWC
  127. AC_MSG_CHECKING(for gcc compiler warnings)
  128. AC_ARG_ENABLE(warnings,
  129. [ --disable-warnings disable compiler warnings],
  130. [if test "${enableval}" = no -o "$GCC" = no; then
  131. AC_MSG_RESULT(no)
  132. WARNINGS=
  133. else
  134. AC_MSG_RESULT(yes)
  135. WARNINGS="-Wall -Wstrict-prototypes -Wmissing-prototypes -Wpointer-arith \
  136. -Wmissing-declarations -Wredundant-decls -Wnested-externs \
  137. -Wsign-compare -Wreturn-type -Wswitch -Wshadow \
  138. -Wcast-qual -Wwrite-strings -Wextra -Wunused-parameter -Wformat=2"
  139. fi], [
  140. if test "$GCC" = yes; then
  141. AC_MSG_RESULT(yes)
  142. WARNINGS="-Wall -Wstrict-prototypes -Wmissing-prototypes -Wpointer-arith \
  143. -Wmissing-declarations -Wredundant-decls -Wnested-externs \
  144. -Wsign-compare -Wreturn-type -Wswitch -Wshadow \
  145. -Wcast-qual -Wwrite-strings -Wextra -Wunused-parameter -Wformat=2"
  146. else
  147. WARNINGS=
  148. AC_MSG_RESULT(no)
  149. fi])
  150. dnl Checks for functions
  151. AC_CHECK_FUNCS(strndup mkstemp mkostemp utimes utime wcwidth strtof newlocale uselocale freelocale memmem pipe2)
  152. dnl Provide implementation of some required functions if necessary
  153. AC_REPLACE_FUNCS(getopt_long asprintf vasprintf strlcpy strlcat getline ctime_r asctime_r localtime_r gmtime_r pread strcasestr fmtcheck dprintf)
  154. dnl Checks for libraries
  155. if test "$enable_zlib" != "no"; then
  156. AC_CHECK_LIB(z, gzopen)
  157. fi
  158. if test "$enable_bzlib" != "no"; then
  159. AC_CHECK_LIB(bz2, BZ2_bzCompressInit)
  160. fi
  161. if test "$enable_xzlib" != "no"; then
  162. AC_CHECK_LIB(lzma, lzma_stream_decoder)
  163. fi
  164. if test "$enable_libseccomp" != "no"; then
  165. AC_CHECK_LIB(seccomp, seccomp_init)
  166. fi
  167. if test "$MINGW" = 1; then
  168. AC_CHECK_LIB(gnurx,regexec,,AC_MSG_ERROR([libgnurx is required to build file(1) with MinGW]))
  169. fi
  170. dnl See if we are cross-compiling
  171. AM_CONDITIONAL(IS_CROSS_COMPILE, test "$cross_compiling" = yes)
  172. dnl Final sanity checks
  173. if test "$enable_zlib" = "yes"; then
  174. if test "$ac_cv_header_zlib_h$ac_cv_lib_z_gzopen" != "yesyes"; then
  175. AC_MSG_ERROR([zlib support requested but not found])
  176. fi
  177. fi
  178. if test "$ac_cv_header_zlib_h$ac_cv_lib_z_gzopen" = "yesyes"; then
  179. AC_DEFINE([ZLIBSUPPORT], 1, [Enable zlib compression support])
  180. fi
  181. if test "$enable_bzlib" = "yes"; then
  182. if test "$ac_cv_header_bzlib_h$ac_cv_lib_bz2_BZ2_bzCompressInit" != "yesyes"; then
  183. AC_MSG_ERROR([bzlib support requested but not found])
  184. fi
  185. fi
  186. if test "$ac_cv_header_bzlib_h$ac_cv_lib_bz2_BZ2_bzCompressInit" = "yesyes"; then
  187. AC_DEFINE([BZLIBSUPPORT], 1, [Enable bzlib compression support])
  188. fi
  189. if test "$enable_xzlib" = "yes"; then
  190. if test "$ac_cv_header_lzma_h$ac_cv_lib_lzma_lzma_stream_decoder" != "yesyes"; then
  191. AC_MSG_ERROR([xzlib support requested but not found])
  192. fi
  193. fi
  194. if test "$ac_cv_header_lzma_h$ac_cv_lib_lzma_lzma_stream_decoder" = "yesyes"; then
  195. AC_DEFINE([XZLIBSUPPORT], 1, [Enable xzlib compression support])
  196. fi
  197. AC_CONFIG_FILES([Makefile src/Makefile magic/Makefile tests/Makefile doc/Makefile python/Makefile libmagic.pc])
  198. AC_OUTPUT