configure.ac 4.1 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154
  1. dnl Process this file with autoconf to produce a configure script.
  2. AC_INIT([file],[5.14],[christos@astron.com])
  3. AM_INIT_AUTOMAKE([subdir-objects foreign])
  4. m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  5. AC_CONFIG_HEADERS([config.h])
  6. AC_CONFIG_MACRO_DIR([m4])
  7. AC_MSG_CHECKING(for builtin ELF support)
  8. AC_ARG_ENABLE(elf,
  9. [ --disable-elf disable builtin ELF support],
  10. [if test "${enableval}" = yes; then
  11. AC_MSG_RESULT(yes)
  12. AC_DEFINE([BUILTIN_ELF], 1, [Define if built-in ELF support is used])
  13. else
  14. AC_MSG_RESULT(no)
  15. fi], [
  16. # enable by default
  17. AC_MSG_RESULT(yes)
  18. AC_DEFINE([BUILTIN_ELF], 1, [Define in built-in ELF support is used])
  19. ])
  20. AC_MSG_CHECKING(for ELF core file support)
  21. AC_ARG_ENABLE(elf-core,
  22. [ --disable-elf-core disable ELF core file support],
  23. [if test "${enableval}" = yes; then
  24. AC_MSG_RESULT(yes)
  25. AC_DEFINE([ELFCORE], 1, [Define for ELF core file support])
  26. else
  27. AC_MSG_RESULT(no)
  28. fi], [
  29. # enable by default
  30. AC_MSG_RESULT(yes)
  31. AC_DEFINE([ELFCORE], 1, [Define for ELF core file support])
  32. ])
  33. AC_MSG_CHECKING(for file formats in man section 5)
  34. AC_ARG_ENABLE(fsect-man5,
  35. [ --enable-fsect-man5 enable file formats in man section 5],
  36. [if test "${enableval}" = yes; then
  37. AC_MSG_RESULT(yes)
  38. fsect=5
  39. else
  40. AC_MSG_RESULT(no)
  41. fsect=4
  42. fi], [
  43. # disable by default
  44. AC_MSG_RESULT(no)
  45. fsect=4
  46. ])
  47. AC_CANONICAL_HOST
  48. case "$host_os" in
  49. mingw32*)
  50. MINGW=1
  51. ;;
  52. *)
  53. MINGW=0
  54. ;;
  55. esac
  56. AC_SUBST(MINGW)
  57. AM_CONDITIONAL(MINGW, test "$MINGW" = 1)
  58. AC_SUBST([pkgdatadir], ['$(datadir)/misc'])
  59. AC_SUBST(fsect)
  60. AM_CONDITIONAL(FSECT5, test x$fsect = x5)
  61. AC_SUBST(WARNINGS)
  62. dnl Checks for programs.
  63. AC_PROG_CC_STDC
  64. AC_USE_SYSTEM_EXTENSIONS
  65. AM_PROG_CC_C_O
  66. AC_C_BIGENDIAN
  67. AC_PROG_INSTALL
  68. AC_PROG_LN_S
  69. LT_INIT([disable-static pic-only])
  70. gl_VISIBILITY
  71. dnl Checks for headers
  72. AC_HEADER_STDC
  73. AC_HEADER_MAJOR
  74. AC_HEADER_SYS_WAIT
  75. AC_CHECK_HEADERS(stdint.h fcntl.h locale.h stdint.h inttypes.h unistd.h)
  76. AC_CHECK_HEADERS(stddef.h utime.h wchar.h wctype.h limits.h)
  77. AC_CHECK_HEADERS(getopt.h err.h)
  78. AC_CHECK_HEADERS(sys/mman.h sys/stat.h sys/types.h sys/utime.h sys/time.h)
  79. AC_CHECK_HEADERS(zlib.h)
  80. dnl Checks for typedefs, structures, and compiler characteristics.
  81. AC_C_CONST
  82. AC_TYPE_OFF_T
  83. AC_TYPE_SIZE_T
  84. AC_CHECK_MEMBERS([struct stat.st_rdev])
  85. AC_CHECK_MEMBERS([struct tm.tm_gmtoff])
  86. AC_STRUCT_TIMEZONE
  87. AC_STRUCT_TIMEZONE_DAYLIGHT
  88. AC_SYS_LARGEFILE
  89. AC_FUNC_FSEEKO
  90. AC_TYPE_MBSTATE_T
  91. AC_STRUCT_OPTION_GETOPT_H
  92. AC_TYPE_PID_T
  93. AC_TYPE_UINT8_T
  94. AC_TYPE_UINT16_T
  95. AC_TYPE_UINT32_T
  96. AC_TYPE_INT32_T
  97. AC_TYPE_UINT64_T
  98. AC_TYPE_INT64_T
  99. AC_FUNC_MMAP
  100. AC_FUNC_FORK
  101. AC_FUNC_MBRTOWC
  102. AC_MSG_CHECKING(for gcc compiler warnings)
  103. AC_ARG_ENABLE(warnings,
  104. [ --disable-warnings disable compiler warnings],
  105. [if test "${enableval}" = no -o "$GCC" = no; then
  106. AC_MSG_RESULT(no)
  107. WARNINGS=
  108. else
  109. AC_MSG_RESULT(yes)
  110. WARNINGS="-Wall -Wstrict-prototypes -Wmissing-prototypes -Wpointer-arith \
  111. -Wmissing-declarations -Wredundant-decls -Wnested-externs \
  112. -Wsign-compare -Wreturn-type -Wswitch -Wshadow \
  113. -Wcast-qual -Wwrite-strings -Wextra -Wunused-parameter -Wformat=2"
  114. fi], [
  115. if test "$GCC" = yes; then
  116. AC_MSG_RESULT(yes)
  117. WARNINGS="-Wall -Wstrict-prototypes -Wmissing-prototypes -Wpointer-arith \
  118. -Wmissing-declarations -Wredundant-decls -Wnested-externs \
  119. -Wsign-compare -Wreturn-type -Wswitch -Wshadow \
  120. -Wcast-qual -Wwrite-strings -Wextra -Wunused-parameter -Wformat=2"
  121. else
  122. WARNINGS=
  123. AC_MSG_RESULT(no)
  124. fi])
  125. dnl Checks for functions
  126. AC_CHECK_FUNCS(strerror strndup strtoul mkstemp mkostemp utimes utime wcwidth strtof)
  127. dnl Provide implementation of some required functions if necessary
  128. AC_REPLACE_FUNCS(getopt_long asprintf vasprintf strlcpy strlcat getline ctime_r asctime_r pread)
  129. dnl Checks for libraries
  130. AC_CHECK_LIB(z,gzopen)
  131. if test "$MINGW" = 1; then
  132. AC_CHECK_LIB(gnurx,regexec,,AC_MSG_ERROR([libgnurx is required to build file(1) with MinGW]))
  133. fi
  134. dnl See if we are cross-compiling
  135. AM_CONDITIONAL(IS_CROSS_COMPILE, test "$cross_compiling" = yes)
  136. AC_CONFIG_FILES([Makefile src/Makefile magic/Makefile tests/Makefile doc/Makefile python/Makefile])
  137. AC_OUTPUT