ltsugar.m4 4.3 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124
  1. # ltsugar.m4 -- libtool m4 base layer. -*-Autoconf-*-
  2. #
  3. # Copyright (C) 2004-2005, 2007-2008, 2011-2015 Free Software
  4. # Foundation, Inc.
  5. # Written by Gary V. Vaughan, 2004
  6. #
  7. # This file is free software; the Free Software Foundation gives
  8. # unlimited permission to copy and/or distribute it, with or without
  9. # modifications, as long as this notice is preserved.
  10. # serial 6 ltsugar.m4
  11. # This is to help aclocal find these macros, as it can't see m4_define.
  12. AC_DEFUN([LTSUGAR_VERSION], [m4_if([0.1])])
  13. # lt_join(SEP, ARG1, [ARG2...])
  14. # -----------------------------
  15. # Produce ARG1SEPARG2...SEPARGn, omitting [] arguments and their
  16. # associated separator.
  17. # Needed until we can rely on m4_join from Autoconf 2.62, since all earlier
  18. # versions in m4sugar had bugs.
  19. m4_define([lt_join],
  20. [m4_if([$#], [1], [],
  21. [$#], [2], [[$2]],
  22. [m4_if([$2], [], [], [[$2]_])$0([$1], m4_shift(m4_shift($@)))])])
  23. m4_define([_lt_join],
  24. [m4_if([$#$2], [2], [],
  25. [m4_if([$2], [], [], [[$1$2]])$0([$1], m4_shift(m4_shift($@)))])])
  26. # lt_car(LIST)
  27. # lt_cdr(LIST)
  28. # ------------
  29. # Manipulate m4 lists.
  30. # These macros are necessary as long as will still need to support
  31. # Autoconf-2.59, which quotes differently.
  32. m4_define([lt_car], [[$1]])
  33. m4_define([lt_cdr],
  34. [m4_if([$#], 0, [m4_fatal([$0: cannot be called without arguments])],
  35. [$#], 1, [],
  36. [m4_dquote(m4_shift($@))])])
  37. m4_define([lt_unquote], $1)
  38. # lt_append(MACRO-NAME, STRING, [SEPARATOR])
  39. # ------------------------------------------
  40. # Redefine MACRO-NAME to hold its former content plus 'SEPARATOR''STRING'.
  41. # Note that neither SEPARATOR nor STRING are expanded; they are appended
  42. # to MACRO-NAME as is (leaving the expansion for when MACRO-NAME is invoked).
  43. # No SEPARATOR is output if MACRO-NAME was previously undefined (different
  44. # than defined and empty).
  45. #
  46. # This macro is needed until we can rely on Autoconf 2.62, since earlier
  47. # versions of m4sugar mistakenly expanded SEPARATOR but not STRING.
  48. m4_define([lt_append],
  49. [m4_define([$1],
  50. m4_ifdef([$1], [m4_defn([$1])[$3]])[$2])])
  51. # lt_combine(SEP, PREFIX-LIST, INFIX, SUFFIX1, [SUFFIX2...])
  52. # ----------------------------------------------------------
  53. # Produce a SEP delimited list of all paired combinations of elements of
  54. # PREFIX-LIST with SUFFIX1 through SUFFIXn. Each element of the list
  55. # has the form PREFIXmINFIXSUFFIXn.
  56. # Needed until we can rely on m4_combine added in Autoconf 2.62.
  57. m4_define([lt_combine],
  58. [m4_if(m4_eval([$# > 3]), [1],
  59. [m4_pushdef([_Lt_sep], [m4_define([_Lt_sep], m4_defn([lt_car]))])]]dnl
  60. [[m4_foreach([_Lt_prefix], [$2],
  61. [m4_foreach([_Lt_suffix],
  62. ]m4_dquote(m4_dquote(m4_shift(m4_shift(m4_shift($@)))))[,
  63. [_Lt_sep([$1])[]m4_defn([_Lt_prefix])[$3]m4_defn([_Lt_suffix])])])])])
  64. # lt_if_append_uniq(MACRO-NAME, VARNAME, [SEPARATOR], [UNIQ], [NOT-UNIQ])
  65. # -----------------------------------------------------------------------
  66. # Iff MACRO-NAME does not yet contain VARNAME, then append it (delimited
  67. # by SEPARATOR if supplied) and expand UNIQ, else NOT-UNIQ.
  68. m4_define([lt_if_append_uniq],
  69. [m4_ifdef([$1],
  70. [m4_if(m4_index([$3]m4_defn([$1])[$3], [$3$2$3]), [-1],
  71. [lt_append([$1], [$2], [$3])$4],
  72. [$5])],
  73. [lt_append([$1], [$2], [$3])$4])])
  74. # lt_dict_add(DICT, KEY, VALUE)
  75. # -----------------------------
  76. m4_define([lt_dict_add],
  77. [m4_define([$1($2)], [$3])])
  78. # lt_dict_add_subkey(DICT, KEY, SUBKEY, VALUE)
  79. # --------------------------------------------
  80. m4_define([lt_dict_add_subkey],
  81. [m4_define([$1($2:$3)], [$4])])
  82. # lt_dict_fetch(DICT, KEY, [SUBKEY])
  83. # ----------------------------------
  84. m4_define([lt_dict_fetch],
  85. [m4_ifval([$3],
  86. m4_ifdef([$1($2:$3)], [m4_defn([$1($2:$3)])]),
  87. m4_ifdef([$1($2)], [m4_defn([$1($2)])]))])
  88. # lt_if_dict_fetch(DICT, KEY, [SUBKEY], VALUE, IF-TRUE, [IF-FALSE])
  89. # -----------------------------------------------------------------
  90. m4_define([lt_if_dict_fetch],
  91. [m4_if(lt_dict_fetch([$1], [$2], [$3]), [$4],
  92. [$5],
  93. [$6])])
  94. # lt_dict_filter(DICT, [SUBKEY], VALUE, [SEPARATOR], KEY, [...])
  95. # --------------------------------------------------------------
  96. m4_define([lt_dict_filter],
  97. [m4_if([$5], [], [],
  98. [lt_join(m4_quote(m4_default([$4], [[, ]])),
  99. lt_unquote(m4_split(m4_normalize(m4_foreach(_Lt_key, lt_car([m4_shiftn(4, $@)]),
  100. [lt_if_dict_fetch([$1], _Lt_key, [$2], [$3], [_Lt_key ])])))))])[]dnl
  101. ])